Conditional Equations with when-Equations

1 WhenEquation

When-equations are used to express instantaneous equations that are only valid at events, e.g. at discontinuities or when certain conditions become true. The conditional equations automatically contain only discrete-time expressions since they become active only at event instants. The two equations in the whenEquation below become active at the event instant when the Boolean expression x > 2 becomes true.

model WhenEquation Real x(start = 1); discrete Real y1(fixed=true); parameter Real y2 = 3; discrete Real y3(fixed=true); equation x = time - y2; when x > 2 then y1 = sin(x); y3 = 2*x + y1 + y2; end when; end WhenEquation;

2 Simulation of WhenEquation

Here WhenEquation is simulated. Then as below the variables can be plotted.

simulate( WhenEquation, stopTime=10 )
plot( { y1, y2, y3, x } )

plot( { y1, y3, x } )

3 WhenSet

If we instead use a Boolean vector expression containing three elements as the conditions, then the two equations will be activated at event instants when either of the three conditions: x > 2, sample(0,2), or x becomes true. Sample is more explained here.

class WhenSet Real x; parameter Real y2 = 3; discrete Real y1(fixed=true); discrete Real y3(fixed=true); equation x = time - y2; when {x > 2, sample(0, 2), x < 5} then y1 = sin(x); y3 = 2*x + y1 + y2; end when; end WhenSet;

4 Simulation of WhenSet

Here WhenSet is simulated.

simulate( WhenSet, stopTime=10 )
plot( { y1, y3, x } )

5 Activate

Special behavior can be specified by when-equations when a simulation starts and finishes by testing the built-in predicates initial() and terminal(). The predicate initial() returns true at the beginning of the simulation when time is equal to time.start and the predicate terminal() returns true at the end of the simulation.

class Activate Real x = 4; Real y, z(fixed=true); equation when initial() then y = x + 3; // Equations to be activated at the beginning end when; when terminal() then z = x - 2; // Equations to be activated at the end of the simulation end when; end Activate;

6 Simulation of Activate

Here Activate is simulated.

simulate( Activate, stopTime=10 )
plot( {x, y, z } )

7 Restrictions on Equations within when-Equations

To make it possible both for a Modelica tool and a person to determine which variables are "results" from a when-equation, Modelica restricts the allowed equations within a when-equation to a form where the result variable is on the left-hand side.

7.1 WhenNotValid

model WhenNotValid Real x, y; equation x + y = 5; when sample(0, 2) then 2*x + y = 7; // Error: not valid Modelica code end when; end WhenNotValid;

7.2 Simulation of WhenNotValid

Here WhenNotValid is simulated. Since the code 2*x + y = 7; is not valid Modelica code the error message Illegal left hand equation in when equation is shown in the failed simulation message below.

simulate( WhenNotValid ) //Should fail!

7.3 WhenValidResult

model WhenValidResult Real x; Real y(fixed=true); equation x + y = 5; // Equation to be used to compute x when sample(0, 2) then y = 7; // - 2*x; // Correct, y is a result variable from the when end when; end WhenValidResult;

7.4 Simulation of WhenValidResult

Here WhenValidResult is simulated.

simulate( WhenValidResult )
plot({x, y})

7.5 Nested When

When-clauses are not allowed to be nested.

model ErrorNestedWhen Real x, y1, y2; equation when x > 2 then when x > 3 then // Error: when-clauses cannot be nested y2 = sin(x); end when; end when; end ErrorNestedWhen;

7.6 Simulation of ErrorNestedWhen

Here ErrorNestedWhen is simulated. Since it is not allowed to have nested when-clauses. there will be an error.

simulate( ErrorNestedWhen ) // Simulation should fail

8 Application of the Single-Assignment Rule on when-Clauses

Two when-caluses may not define the same variable. Without this rule that may actually happen for the erroneous model DoubleConflict below a conflict between the equations will occur if both conditions become true at the same time instant.

8.1 DoubleWhenConflict

model DoubleWhenConflict Real x; Boolean close; // Erroneous model: close defined by two equations! equation when x > 2 then close = true; end when; when x > 3 then close = false; end when; end DoubleWhenConflict;

8.2 Simulation of DoubleWhenConflict

Since the variable close cannot be defined by two equations the model could not be translated.

simulate( DoubleWhenConflict )

"Simulate failed to translate model."