Using Array Concatenation and Slices

The following usage examples show a few common programming situations where both array concatenation and array slices are involved, and how to do this correctly in order to avoid certain mistakes.

1 Appending an Element to Vectors and Row/Column Matrices

The first equations set XA1, XA2, XA3 and XA4 equal to row matrices and XB1, XB2 equal to column matrices respectively, created by appending an additional element to row/column matrices PA and PB.

class AppendElement Real[1, 3] PA = [1, 2, 3]; // A row matrix value Real[3, 1] PB = [1; 2; 3]; // A column matrix value Real[3] q = {1, 2, 3}; // A vector value Real[1, 4] XA1, XA2, XA3, XA4; // Row matrix variables Real[4, 1] XB1, XB2; // Column matrix variables Real[4] y; // Vector variable equation XA1 = [PA, 4]; // Append OK, since 4 is promoted to {{4}} XA2 = cat(2, PA, {{4}}); // Append OK, same as above but not promoted XB1 = [PB; 4]; // Append OK, result is {{1}, {2}, {3}, {4}} XB2 = cat(1, PB, {{2}}); // Append OK, same result y = cat(1, q, {4}); // Vector append OK, result is {1, 2, 3, 4} XA3 = [-1, zeros(1, 2), 1]; // Append OK, result is {{-1, 0, 0, 1}} XA4 = cat(2, {{-1}}, zeros(1, 2), {{1}} ); // Append OK, result is {{-1, 0, 0, 1}} end AppendElement;

1.1 Simulation of AppendElement

simulate( AppendElement )

Take a look at the value at time=0:

val(y[3],0)
plot({XA1[1,3],y[2]})

2 Composing a Blocked Matrix Board from Submatrices

The following example shows three very similar ways of constructing a blocked matrix from submatrices. The first two variants follow the rule of always making sure that returned array slices as arguments to the special purpose concatenation operators are matrices. The third variant breaks this rule, since two of the array slices return vectors, causing an error.

2.1 BlockMatrix

class BlockMatrix Real[3,3] P = [1, 2, 3; 4, 5, 6; 7, 8, 9]; // A 3x3 matrix value Real[6, 6] Q; // Q consists of four 3x3 matrix blocks to be defined // by P apart from sign equation Q[1:3, 1:3] = P; // Upper left block Q[1:3, 4:6] = [Q[1:3, 1:2], -Q[1:3, {3}]]; // Upper right block Q[4:6, 1:3] = [Q[1:2, 1:3]; -Q[{3}, 1:3]]; // Lower left block Q[4:6, 4:6] = P; // Lower right block end BlockMatrix;
simulate(BlockMatrix)

2.2 BlockMatrix2

class BlockMatrix2 Real[3, 3] P = [1, 2, 3; 4, 5, 6; 7, 8, 9]; Real[6, 6] Q; equation Q[1:3, 1:3] = P; // Upper left block Q[1:3, 4:6] = [Q[1:3, 1:2], -Q[1:3, 3:3]]; // Upper right block Q[4:6, 1:3] = [Q[1:2, 1:3]; -Q[3:3, 1:3]]; // Lower left block Q[4:6, 4:6] = P; // Lower right block end BlockMatrix2;
simulate(BlockMatrix2)

2.3 BlockMatrix3

class BlockMatrix3 Real[3, 3] P = [1, 2, 3; 4, 5, 6; 7, 8, 9]; Real[6, 6] Q; equation Q[1:3, 1:3] = P; // OK! Q[1:3, 4:6] = [Q[1:3, 1:2], -Q[1:3, 3]]; // OK, correct promotion Q[4:6, 1:3] = [Q[1:2, 1:3], -Q[3, 1:3]]; // ERROR! Q[4:6, 4:6] = P; // OK! end BlockMatrix3;
simulate(BlockMatrix3)

3 Cyclic Permutation of Matrix Rows or Columns

Cyclic permutation can be achieved by a combination of concatenation operations and array slices or just array slices using a permutation vector.

class CyclicPerm Real[1, 3] WO = [1, 2, 3]; // Row matrix Real[2, 3] XO = [1, 2, 3; 4, 5, 6]; // Matrix with two rows Real[1, 3] W; // Permuted row matrix Real[2, 3] X; // Permuted matrix with two rows Integer[3] p = {2, 3, 1}; // Permutation vector algorithm W := [[2, 3], 1]; // OK, result: [2, 3, 1] = {{2, 3, 1}} W := [{{2, 3}}, {{1}}]; // OK, same result: {{2, 3, 1}} W := [WO[{1}, 2:3], WO[{1}, {1}]]; // OK, result: {{2, 3, 1}} W := [WO[1:1, 2:3], WO[1:1, 1:1]]; // OK, same result: {{2, 3, 1}} W := WO[:, p]; // OK, same result: {{2, 3, 1}} W := cat(2, WO[1:1, 2:3], WO[1:1, 1:1]); // OK, same result: {{2, 3, 1}} W := [WO[1, 2:3], WO[1, 1]]; // Error, since WO[1, 2:3] is a vector X := [XO[:, 2:3], XO[:, {1}]]; // OK, X becomes [2, 3, 1; 5, 6, 4] X := XO[:, p]; // OK, X becomes [2, 3, 1; 5, 6, 4] X[{1},:] := [XO[{1}, 2:3], XO[{1}, {1}]]; // OK, X becomes [2,3,1; 5,6,4] X[1, :] := [XO[1, 2:3], XO[1, 1]]; // ERROR, incompatible dimensions end CyclicPerm;

3.1 Simulation of CyclicPerm

simulate( CyclicPerm )